ASP程序代碼執行時間統計類_ASP教程

編輯Tag賺U幣

教程Tag：暫無Tag,歡迎添加,賺取U幣!

推薦：代碼指導用ASP木馬實現FTP和解壓縮
我想大家都有一些開了80端口的肉雞吧，如果是國內的出于安全就不要往下看了，如果不不妨往下看一下，小弟獻丑了，以求拋磚引玉。在肉雞上放網站最麻煩的可能就是更新和上傳大量的文件了，終

第一次寫ASP類，實現功能：分段統計程序執行時間，輸出統計表等。

程序代碼：

以下為引用的內容：

Class ccClsProcessTimeRecorder
''ASP程序代碼執行時間統計類

Private ccInti,ccIntNonceTime,ccIntDecimal
Private ccIntStartTime,ccIntEndTime,ccIntNow,ccIntNonce
Private ccStrInterval,ccStrEvent,ccStrTime,ccStrStatisticLog,ccStrFormatInterval
Private ccArrEvent,ccArrTime

Private Sub Class_Initialize
ccStrInterval = "|" ''默認分隔符
ccIntDecimal = 4 ''小數點后位數
ccStrEvent = ""
ccStrTime = ""
ccStrFormatInterval = "<br />" & vbCrLf
ccIntStartTime = Timer
ccIntNow = ccIntStartTime
ccIntNonce = ccIntStartTime
End Sub

Public Sub Record(ccStrEventName)
ccStrEvent = ccStrEvent & ccStrInterval & Replace(ccStrEventName,ccStrInterval,"")
ccStrTime = ccStrTime & ccStrInterval & FormatNumber(Timer-ccIntNow,ccIntDecimal,True,False,True)
ccIntNow = Timer
End Sub

Public Property Let Format(ccStrFormatType)
If LCase(Trim(ccStrFormatType)) = "html" Then
ccStrFormatInterval = "<br />" & vbCrLf
Else
ccStrFormatInterval = vbCrLf
End If
End Property

Public Function Statistic
If InStr(ccStrEvent,ccStrInterval) > 0 Then
ccIntEndTime = Timer
ccArrEvent = Split(ccStrEvent,ccStrInterval)
ccArrTime = Split(ccStrTime,ccStrInterval)
ccStrStatisticLog = ccStrStatisticLog & "Process Time Record" & ccStrFormatInterval
ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
For ccInti = 1 To UBound(ccArrEvent)
ccStrStatisticLog = ccStrStatisticLog & ccArrEvent(ccInti) & " : " & ccArrTime(ccInti) & " s" & ccStrFormatInterval
Next
ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
ccStrStatisticLog = ccStrStatisticLog & "Total : " & FormatNumber(ccIntEndTime-ccIntStartTime,ccIntDecimal,True,False,True) & " s"
Statistic = ccStrStatisticLog
Else
Statistic = "No Record"
End If
End Function

Public Function Nonce
ccIntNonceTime = FormatNumber(Timer-ccIntNonce,ccIntDecimal,True,False,True)
ccIntNonce = Timer
Nonce = ccIntNonceTime
End Function

Public Function Total
Total = FormatNumber(Timer-ccIntStartTime,ccIntDecimal,True,False,True)
End Function

End Class

類屬性：

1、Format

輸出時是否帶HTML換行標簽

-html:輸出HTML換行標簽和文本換行符(默認)

-text:僅輸出文本換行符

類方法：

1、Record("Code Name")

統計自上一次調用Record方法至現在的時間(第一次調用時統計聲明類時至調用時時間)，最后在Statistic中輸出類函數：(即時返回信息)

1、Nonce

輸出自上一次調用nonce函數至現在的時間(第一次調用時統計聲明類時至調用時時間)